dnl Process this file with autoconf to produce a configure script for gzip
dnl
AC_INIT(gzip.c)
AM_INIT_AUTOMAKE(gzip, 1.3)
AM_CONFIG_HEADER(config.h)
AC_CANONICAL_HOST
AC_PROG_CC
AC_OBJEXT
AC_SYS_LARGEFILE

dnl
dnl Try to assemble match.S with and without leading underline.
dnl cc -E produces incorrect asm files on SVR4, we must use /lib/cpp.
dnl Also, "gcc -E match.s" ignores -E, so we must use match.S.
echo checking for underline in external names
test -z "$ASCPP" -a -f /lib/cpp && ASCPP=/lib/cpp
test -z "$ASCPP" && ASCPP="$CC -E"
cat > conftest.c <<EOF
int foo() {return 0;}
EOF
eval "$CC -c conftest.c > /dev/null 2>&1"
if nm conftest.$OBJEXT | grep _foo > /dev/null 2>&1 ; then
  :
else
  ASCPP="${ASCPP} -DNO_UNDERLINE"
fi
rm -f _match.$OBJEXT conftest.c conftest.$OBJEXT
if echo "$DEFS" | grep NO_ASM >/dev/null; then
  :
else
  echo checking for assembler
  if eval "$ASCPP $srcdir/match.S > _match.s 2>/dev/null"; then
    if test ! -s _match.s || grep error < _match.s > /dev/null; then
      :
    elif eval "$CC -c _match.s >/dev/null 2>&1" && test -f _match.$OBJEXT; then
      AC_DEFINE(ASMV, ,
	[Define if an assembler version of longest_match is available.])
      LIBOBJS="$LIBOBJS match.$OBJEXT"
      # Work around automake 1.4 bug
      : LIBOBJS="$LIBOBJS match.o"
    fi
  fi
  rm -f _match.s _match.$OBJEXT
fi
dnl
AC_AIX
AC_MINIX
AC_EXEEXT
AC_ISC_POSIX
AC_C_CONST
AC_STDC_HEADERS
AC_CHECK_HEADERS(fcntl.h limits.h memory.h \
  stdlib.h string.h sys/utime.h time.h unistd.h utime.h)
AC_CHECK_FUNCS(utime)
AC_HEADER_DIRENT
AC_TYPE_SIGNAL
AC_TYPE_SIZE_T
AC_TYPE_OFF_T
AC_SYS_INTERPRETER
case $interpval in
yes) SEDCMD='1d';;
*) SEDCMD='';;
esac

AC_PREFIX_PROGRAM(gzip)
AC_SUBST(LIBOBJS)dnl
AC_SUBST(CFLAGS)dnl
AC_SUBST(ASCPP)dnl
AC_SUBST(SEDCMD)dnl
AC_OUTPUT(Makefile)
